((Entity#null) && (Entity.imageName#null)) && (Entity.imageName#"")

<img src="/images/post-
&lt;!--#4DTEXT Entity.uuidKey--&gt; : Indéfinie/
&lt;!--#4DTEXT Entity.imageName--&gt; : Indéfinie" 
     class="w-48 h-36 object-cover rounded-lg">

Function save($vo_POST : Object)->$vo_WebResponse : cs.bspkComponent.WebFormController
    /* parameters 
        vt_DetailUuid:select:getBlocsNameCollection:["wrapper"]:tomSelect:label:block detail
        vt_SendAllObjectsOfBlocName:hidden:vt_DetailUuid
    */
    /*
The commented lines above are mandatory, their purpose is to indicate which elements of the page will be 
transmitted when the form is submitted (when clicking the save button) This will add a selection list in the dev panel in 
the configuration  of the button's click event to allow us to select a container whose included form elements will all be transmitted
    */

// Are we creating or editing?
If ($vo_POST.pk=Null)
    $Post:=This.new()
Else 
    $Post:=This.get($vo_POST.pk)
End if 

$Post.title:=$vo_POST.vt_FieldValue.title
$Post.summary:=$vo_POST.vt_FieldValue.summary
$Post.content:=$vo_POST.vt_FieldValue.content
$Post.publicationDate:=$vo_POST.vt_FieldValue.date
$Post.isPublished:=($vo_POST.vt_FieldValue.status="Published")

//cleaning of the title to become a slug
//not the most efficient and complete way but it's only a quickstart :-)
$Post.slug:=Lowercase(Uppercase($vo_POST.vt_FieldValue.title))
$Post.slug:=Replace string($Post.slug; " "; "-")
$Post.slug:=Replace string($Post.slug; "'"; "-")
$Post.slug:=Replace string($Post.slug; "!"; "-")
$Post.slug:=Replace string($Post.slug; "?"; "-")
$Post.save()

//saving the image
$vt_ImageFolder:=Get 4D folder(Database folder)+"BWEB"+Folder separator+"images"+Folder separator+"post-"+$Post.uuidKey
If (Test path name($vt_ImageFolder)#Is a folder)
    CREATE FOLDER($vt_ImageFolder;*)
End if 

If ($vo_POST.vt_FieldValue.image#"")
    $vo_Blob:=BSPK_BASE64_TO_BLOB(JSON Parse($vo_POST.vt_FieldValue.image))
    $vt_ImageName:="small"+String(Milliseconds)+".jpg"
    BLOB TO DOCUMENT($vt_ImageFolder+Folder separator+$vt_ImageName; OB Values($vo_Blob)[0])
    $Post.imageName:=$vt_ImageName
    $Post.save()
End if 

//response : in this case return to the root page
$vo_WebResponse:=cs.bspkComponent.WebFormController.new()
$vo_WebResponse.vc_Action.push({vt_Action: "redirect"; vt_Url: "/"})

Function delete($vo_POST : Object)->$vo_WebResponse : cs.bspkComponent.WebFormController
    //are we deleting from the detail of the post or from the trash icon in the listbox?
    //If the Entity process variable is set, we are in the detail page
    If (Entity#Null)
        $Post:=Entity
    Else 
        //if we are deleting the post from the listbox directly, we can use the $vo_POST.triggerObject.vt_RowPk to get the id of the POST
        $Post:=This.get($vo_POST.triggerObject.vt_RowPk)
    End if 
    //delete the image folder and file
    $vt_ImageFolder:=Get 4D folder(Database folder)+"BWEB"+Folder separator+"images"+Folder separator+"post-"+$Post.uuidKey
    If (Test path name($vt_ImageFolder)=Is a folder)
        DELETE FOLDER($vt_ImageFolder; Delete with contents)
    End if 
    $Post.drop()
    //response
    $vo_WebResponse:=cs.bspkComponent.WebFormController.new()
    If (Entity#Null)
        //we are deleting from the detail page
        //we add 2 actions :
        // - changeUrl to remove the pk parameter
        // - openAlert to open a toast alert to confirm the delete of the post
        $vo_WebResponse.vc_Action.push({vt_Action: "changeUrl"; vc_ArgumentToChange: New collection({name: "pk"; value: ""})})
        $vo_WebResponse.vc_Action.push({vt_Action: "openAlert"; vt_AlertTitle: ""; vt_AlertMessage: "Post deleted !!"; vt_AlertType: "success"; vl_AlertDuration: 3})
        //and we reload the mainContent block (the entire page)
        $vo_WebResponse.reloadBlock("mainContent")
    Else 
        //we are deleting the post from the listbox
        //we only add the action openAlert to confirm the delete of the post
        //and the we only reload our listbox of posts
        $vo_WebResponse.vc_Action.push({vt_Action: "openAlert"; vt_AlertTitle: ""; vt_AlertMessage: "Post deleted !!"; vt_AlertType: "success"; vl_AlertDuration: 3})
        $vo_WebResponse.reloadBlock("listbox")
    End if

Function removePostImage()->$vo_WebResponse : cs.bspkComponent.WebFormController
    //remove the image from the entity
    Entity.imageName:=""
    Entity.save()
    //delete the image folder and file
    $vt_ImageFolder:=Get 4D folder(Database folder)+"BWEB"+Folder separator+"images"+Folder separator+"post-"+Entity.uuidKey
    If (Test path name($vt_ImageFolder)=Is a folder)
        DELETE FOLDER($vt_ImageFolder; Delete with contents)
    End if 
    //response
    $vo_WebResponse:=cs.bspkComponent.WebFormController.new()
    $vo_WebResponse.reloadBlock("featured-image")